Local string &reportDefinition, &connQueryName, &connQueryXMLString, &sDirSep, &sWorkDir, &sOutPutPath;
Local PSXP_RPTDEFNMANAGER:ReportDefn &reportDefnObject;
Local Record &connQueryPromptRec;
Local PT_CONQRS:CONQRSMGR &connQueryObject;
Local array of PT_CONQRS:QUERYITEMPROMPT &connQueryPromptsArray;
Local number &nCounter;
Local File &connQueryXMLFile;

Declare Function DeleteLocalDirectory PeopleCode PSXPFUNCLIB.FUNCLIB FieldFormula;
Declare Function GetDirSeparator PeopleCode PSXPFUNCLIB.FUNCLIB FieldFormula;

&sDirSep = GetDirSeparator();
&sWorkDir = GetEnv("PS_SERVDIR") | &sDirSep | "files" | &sDirSep | "XMLP" | &sDirSep | WWPC0002_WW_AET.PROCESS_INSTANCE.Value | "_" | WWPC0002_WW_AET.EMPLID.Value;
CreateDirectory(&sWorkDir, %FilePath_Absolute);

/** Define Report Defn & Connected Query Name **/
&reportDefinition = "WWPC0002";
&connQueryName = "WWPC0002";

try

/** Start by creating the Connected Query Object **/
&connQueryObject = create PT_CONQRS:CONQRSMGR("", &connQueryName);
/** If it can't be opened, throw an error **/
If Not (&connQueryObject.Open( False)) Then
Error ("Failed to open Connected Query.");
End-If;
/** Validate that all PSQueries within the Connected Query Exist **/
If Not (&connQueryObject.Validate()) Then
Error ("Unable to validate Connected Query.");
End-If;

/** Return an Array of Records with the prompts for each Query within the Connected Query **/
&connQueryPromptsArray = &connQueryObject.QueriesPromptsArray;
/** Loop through the Connected Queries and fill in each query's prompts as needed **/
For &nCounter = 1 To &connQueryPromptsArray.Len
&connQueryPromptRec = &connQueryPromptsArray [&nCounter].QueryPromptRecord;
&connQueryPromptRec.EMPLID.Value = WWPC0002_WW_AET.EMPLID.Value;
If &connQueryPromptsArray [&nCounter].QueryName = "WWPC0029" Or
&connQueryPromptsArray [&nCounter].QueryName = "WWPC0035" Then
&connQueryPromptRec.PAY_END_DT.Value = WWPC0002_WW_AET.PAY_END_DT.Value;
Else
&connQueryPromptRec.EFFDT.Value = WWPC0002_WW_AET.PAY_END_DT.Value;
End-If;
End-For;

/** Use the RunToXMLFormattedString method to immediately execute the Connected Query to a String object **/
&connQueryXMLString = &connQueryObject.RunToXMLFormattedString(&connQueryPromptsArray);

/** However, since it is "formatted" XML Publisher will insert Carriage Return and Line Feeds in the report. **/
&connQueryXMLString = Substitute(&connQueryXMLString, ">" | Char(13) | "~", ">");
&connQueryXMLString = Substitute(&connQueryXMLString, ">" | Char(10) | "~", ">");

/** Now that the string is without formatting, write it out to an XML file. **/
&connQueryXMLFile = GetFile(&sWorkDir | &sDirSep | "WWPC0002.xml", "W", %FilePath_Absolute);
&connQueryXMLFile.WriteLine(&connQueryXMLString);
&connQueryXMLFile.Close();

/** Create the Report Definition Object and Get() the report **/
&reportDefnObject = create PSXP_RPTDEFNMANAGER:ReportDefn(&reportDefinition);
&reportDefnObject.Get();

/** Since the Report Definition's Data Source is an XML file, we can pass in the file we created at runtime **/
&reportDefnObject.SetRuntimeDataXMLFile(&sWorkDir | &sDirSep | "WWPC0002.xml");

/** get output directory path **/
SQLExec("SELECT PRCSOUTPUTDIR FROM PS_CDM_LIST WHERE PRCSINSTANCE = :1", WWPC0002_WW_AET.PROCESS_INSTANCE, &sOutPutPath);
&reportDefnObject.OutDestination = &sOutPutPath;

/** Process the report, thus running XML Publisher against the XML file that was created from the Connected Query **/
&reportDefnObject.ProcessReport("", "ENG", %Date, "PDF");

/** Rename the Report File Name Based on Employee Id **/
&reportDefnObject.ReportFileName = WWPC0002_WW_AET.EMPLID.Value;

/** publish report **/
&reportDefnObject.Publish("", "", "", WWPC0002_WW_AET.PROCESS_INSTANCE.Value);

catch Exception &Ex
Error (&Ex.ToString());
end-try;